Skip to Content

Some tunes from 17th to 19th century


(HINT: To create a nice printable PDF of this tunebook, copy the URL of this page and use the ABC tunebook print utility!)

Preface

This collection contains a selection of personal favourites from 17th to 19th century, including some not so well known tunes from Playford's collection as well as from some French sources.

Many of these are extremely beautiful and definitely worth being revived, in my opinion. I hope to provide some MP3s as soon as possible.

ABC
X:1
T:Mr. Lane's Minuet
N:Barlow Nr. 329
O:England
C:trad.
N:Playford again... Another one for a fine bourree
K:Dm
M:3/4
L:1/4
d>e^c |dAf |efd |e/d/^c/=B/A |d>e^c |dAf |efd |e3 :|
|: fcc |A/B/cc |dGG |E/F/GG |F/G/AA |B/c/d=B|c/d/e^c |d3 :|]%%
X:1
T:Whely House
C:trad.
O:England
N:from Playford collection
N:Works as a Scottishe
K:G
M:4/4
L:1/8
d2d2 d2B2 |A>Bc>d B2G2 |c>Bc>d e>fe>d |^c>ae>g f2 d2 :|]
|: =f2f>g e>ce>g |B>^c (c3/B//c//) d2B2 |c>de>=f d>e^f>g |a>cB>b a2g2 :|] %%
X:1
T:Waltzer
S:Clarchies Vol. 20 p.37
Z:ABC transcription Stephan "Stoney" Steiner
K:Eb
M:3/8
L:1/16
V:1
P:A
B2 |[G3e3]GBe |d3Bd2 |f2(dfaf) |g3eB2 |[G3e3]GBe |(d3Bd2) |!wedge!f2(dfaf)|e2z2 :|
P:B
bc'b|a3(dfa)|g3Beg|f2dfaf |(e2B)(bc'b)|(b2a).d.fa|(a2g).B.e.g|(gf)d(fa)d|e2 z "D.C.":|
V:2
L:1/16
B2 |[B,2G2][B,2G2][B,2G2]|[B,2A2][B,2A2][B,2A2]|[B,2A2][B,2A2][B,2A2]|[B,2G2][B,2G2][B,2G2]|[B,2G2][B,2G2][B,2G2]|[B,2A2][B,2A2][B,2A2]|[B,2D2][B,2D2][B,2D2]|[G,2E2]z2 :|
(BcB)|(DFA).A.A.A|(EGB).B.B.B|DFAFDF|B,EGBcB|(DFA).A.A.A|(B,EG).G.G.G|(BDF).F.F.F|[G,2E2]z :|
%%
X:6
T:Whely House
N:from Playford collection
N:Works as a Scottishe
K:F
M:4/4
L:1/8
c2c2 c2A2 |G>AB>c A2F2 |B>AB>c d>ed>c |=B>gd>f e2 c2 :|]
|: _e2e>f d>Bd>f |A>=B (B3/A//B//) c2A2 |B>cd>_e c>d=e>f |g>BA>a g2f2 :|]%%
X:1
T:Daniel Cowper
O:England
N:A splendid tune from Playford
N:Barlow Nr. 321
M:2/2
L:1/4
K:D
AddB|BeeA|AddB|f3d :][: f>g a(g/f/)|g>f e(d/c/)| f>g a(g/f/)|
g2e2 |f>g a(g/f/)|g>f e(d/c/)|A>d d(c/B/)|f3 d :]
%%
X:17
T:Whitehall Minuet
N:Yet another "Bourree 3 temps" from Playford (if played without B repeat)
N:Barlow Nr. 477
K:Dm
M:3/4
L:1/8
d2A2G2 |F4 E2 |F2 DEFG |AGA=B^cA|d2A2G2|F4 E2 |
F2 DEFG |A6 :: fg a2 a2 |a4 a2 |gfga g2 |g2 b4 |
a2 bagf |e2 a4 |f2 gfed |^c3 =B A2 |fg a2 a2 |a4 a2 |
gfgaga |g2b4 |a2 bagf |e2a4 |f2 gfef |d6 :|]%%
X:1
T:Maid's Morris
S:Playford
N:Barlow Nr. 304
N:Makes a fine Polka
N:This version is a mix of the older and the newer setting from
N:different Playford editions
K:C
M:4/4
L:1/4
G|cc/d/ B/B/c|Bd2 c/B/|cA A^f |g3 :: g|a f2e/f/|g e2 e|
fA Ad |BGG f/g/|a/g/f fe/f/|g/f/e/d/ cd|BG/A/ B/c/d/e/ |c3 :|]%%
X:1
T:(The) Resolution
T:The Quaker's grace
S:Playford
N:Barlow Nr. 528
K:D
M:4/4
L:1/4
d/c/|dA B d/c/|dD E d/c/|dA (B/c/)(d/E/)|(G/F/)(E/D/) D :| F/G/|AA AB/c/|
dddc/d/|BBBc/d/|e/f/e/d/ c d/c/|dA B d/c/|dD E d/c/|
dA (B/c/)(d/E/)|(G/F/)(E/D/) D d/e/ |fd/c/ Bc/d/|ec/B/^Af/e/|de/f/ (g/f/)(e/d/)|
c2 B d/c/|dA B d/c/|dD E d/c/|dA (B/c/)(d/E/)|(G/F/)(E/D/) D |]%%
X: 1
T:Copenhagen Waltz
M:3/4
L:1/8
O:England
K:C
|: e |: (e |: g2|(a2g2)e2|c4 g2|a2g2e2|d4g2|a2g2e2|cB ce ge|dc de fd|c4 :|]%%
%%partsbox 1
X:1
T:Menuet de la chaine
C:Uit het vioolmanuscript van Wandembrille
O:Namur 1778
Z:Eli De Coninck
M:3/4
L:1/8
Q:1/4=120
K:Dm
%%MIDI program 40
%%staves [1 2]
P:A
V:1
A2|: "Dm"d^c de fg| "F"a3g a2| "Gm"b2 a2 g2| "A"fe fg fe|
"Dm"d^c de fg| "F"a3g a2| "Gm"b2 a2 g2|1 "A"f4 e2:|2 "A"f4||
V:2
L:1/4
z|: D2E| F3| G3| A2A,|
D2E| F3| G3|1 A3:|2 A2||
%%staves [1 2]
P:B
V:1
|:A2| "Dm"a2 a2 b2| "Gm/E"g3f ef| "A"g2 g2 a2| "Bb"f4 "C"e2|
"Dm"d^c de fd| "C"ed ef ge|1 "Bb"a2 g2 f2| "A"e4:|2 "Bb"(3bag f2 "A"e2|\
M:6/8
Q:3/8=120
"Dm"d6-|d3||
V:2
L:1/4
|:z| D3| E3| E3| D2 E|
F3| E3|1 D3| ^C2:|2 D2 ^C|\
M:6/8
L:1/8
Q:3/8=120
D6-| D3||
%%staves 1
P:C
M:6/8
|:fgf| "Dm"fga agf| "C"e2e fef| "Bb"d2f e2d| "A"^c2A fgf|
"Dm"fga agf| "C"e2e fef| "Bb"d2f "A"ed^c|1 "Dm"d3:|2 "Dm"d4|]
%%
X:1
T:Mount Hills
S:Playford
N:Barlow Nr. 456
K:D
M:4/4
L:1/4
daff |e/f/e/d/ cA |daff |a (g/f/) e2 |daff |e/f/e/d/ cA |d(c/B/)g(f/e/) |c2d2 :|
|:c>d ef |gfe(d/c/)|dBga |f2e2 |a/b/a/g/ff |ddB>f |g(f/e/) (d/c/)(d/e/)|e2 d2 :| %%
X:1
T:Anglaise
Z:Stephan "Stoney" Steiner
S:Clarchies Vol. 23 p.44
M:2/4
L:1/8
K:A
f>ga>a |g>ec>c |d>ef>f |e>cA>A |G>Bd>d |c>ec>A |F>AG>B |A2 A2 :|
|: E>GB>d |c>ec>A |F>AG>B |A>ce>e |G>Bd>d |c>ec>A |F>AG>B |A2 A2 :| %%
X:1
T:Anglaise
Z:Stephan "Stoney" Steiner
S:Clarchies Vol. 23 p.45
M:2/4
L:1/8
K:D
d>fa>a|d>fa>a|g>ec>c|g>ec>c|d>fa>a|d>fa>a|B>dc>e |d2 D2 :|
|: e>c A>g |(3fag (3fed | e>c A>g |f>aa>a |e>c A>g |f>aa>a |B>dc>e |d2 d2 :| %%
X:1
T:Anglaise
Z:Stephan "Stoney" Steiner
S:Clarchies Vol. 26 p.45
M:2/4
L:1/8
K:F
a>g |"F"f>c "Bb"(d/c/B/c/) |"F"A>c (d/c/B/c/) |"Bb(Gm)"d>f "C7"e>g |"F"f>c a>g |
"F"f>c "Bb" (d/c/B/c/) |"F"A>c (d/c/B/c/) |"Gm(Bb)"d>B "C"G>E |"F"F2 :: "Dm(F)"A>d |"A"^c>A A>A |"A7"G>B E>G |
"Dm"F>A d>d |f>d A>d |"A7"^c>e g>g |"Dm"d>f a>a |"Gm"b>g "A"e>a |"Dm"f2 :| %%
X:1
T:Anglaise
S:Clarchies Vol. 26 p.44
Z:Stephan "Stoney" Steiner
K:F
M:2/4
L:1/8
"F"f>a "C7"g>f |e>c "Am(F)"c>c |"Bb"d>f "C7"e>g |"F"f>g a>f |"Bb"d>f e>d |"F"c>A A>c |
"C7"B>G E>G |"F"F2 F2 :: "Dm"A>F D>D |"A"^C>E A>C |"Dm"D>F A>d |
"A"^c>e A>A |"Dm"a f2 d |"Gm6"B G2 E |"Dm"A>d "A"c>e |"Dm"d2 d2 :| %%
X:1
T: La Holtherman
Z:Stephan Steiner
S:Clarchies - Recueil des Contre-danses et Waltzes (c.1800)
K:Am
M:6/8
L:1/8
"$"E|.A(cB) A2c|(e2c) ABc |.B(b^g) edB|(ce).cB2E|,A(cB) Ace |f3- fdB|(AB).c B^GE |A2z z ||
|:^GA |Bd3 cB|A c3 BA |^g e3 dB |c2 (a ^g)^GA |Bd3 cB|ca3 fd |c2A B2^G |A3 z "$":|
GAB|cGE CEG |cGe ceg |a2 g fed |(c2B) GAB |cGE CEG |cGe cge |a2 g fdB |(d3 c2) "$"||
%%
X:1
T:La Fr\'ed\'erika
K:C
Z:Stephan Steiner
M:2/4
L:1/8
P:A (Play parts A-B-A-C-A)
(c|A)(e c)a |(a2 ^g)b|^ge2d/B/|"tr"c/B/c/d/ e"tr"c |A(e c).a |(g2 f)d/B/|cc {c}B/A/B/c/|(B2 A) ||
P:B
"tr"c|G"tr"e c"tr"g |e c'2 "tr"f |.d"tr"B .G.f |e .c2 "tr"c| G"tr"ecg |ea (g/f/)e/d/ |(c/B/) g2 f/d/|c2 z1 ||
P:C
e|(ac') ^gb |ae e"tr"e |fd ^gb |aa/c'/ ee |(ac') ^gb |ae'e'e'|c'c' b/c'/d'/b/ |a2 z ||
%%
X:1
T:La petitte lefevre
S:Clarchies: Recueil des Contre-danses et Waltzes
Z:Stephan Steiner
K:G
M:6/8
L:1/8
P:A
"$"Bd |(gf).d (cA)B |G2G GAB |c2c cde |(d2c) BBd |(gf).d (cA).B |G2 G GAB |cde (ed)F |(A3G) ||
P:B
|: FG |ADD Ddc |BGG Ged |^cde (fg).c |(e3 d)FG|ADD Ddc |BGG Ged|^cde (fg).c |(e3 d) "$":|
P:C
K:Gm
Bd |g3 dBg |dbg d'bg |ca^f ded |(d2c) BBd |g3 dBg |dbg d'bg |d2 d d=e^f |(a3 g) "$"|| %%
X:1
T:German Dance KV 536/2
C:Wolfgang Amadeus Mozart
N:A version of the trio part got known as "Michael Turner's Waltz" in England
K:G
M:3/4
L:1/8
d2|g2 g2 "tr"gf/g/|a2 a2 "tr"ag/a/|b2b2c'2|a2 z2 d2 |a2 a2 "tr"ag/a/|b2 b2 "tr"ba/b/|c'2a2d'2 |g2 z2 :|
|:d2 |D4 EF |GABcdB |c2A2F2 |D4 d2 |D4 EF |GABcdB |c2A2F2|G2 z2 :|
P:Trio
GA|B2B2cA|d2d2gf|{f}e2e2ge|{e}d2d2GA|B2B2cA|d2d2cA|G2G2AB|G2z2 :|
|:AB|c2cdBc |A4 Bc |d2decd|B4 gf|{f}e2e2 ge |{e}d2d2 GA |B2 BcAB |G4 :|
%%
X:1
T:L'Est\'ephanie
Z:Stephan "Stoney" Steiner
K:G
M:2/4
L:1/16
V:1
P:A
"$"(db)gg|g2bg (db).g.g|g2bg fgab |c'3b agfe |d2d'2 (db)gg|g2bg (db).g.g|g2bg fgab |c'2c'b agfa |g4 ||
P:B
(db)gg|g3f edcB |dc c4 AG |FAce (^cd)(Ad)|(=c2B2) (db).g.g|g3f edcB |
(dc) c4 (AG) |1 (GF)(ed) d3F |G4 :||2 FAce dDEF |G4 ||
P:C
BBBB |(Bg) g4 (fe) |(Ba)a4 (f^d)|B2B4 AF |GFE2 B2B2 |(Bg) g4 (fe) |(Ba)a4 Gf |bgfe ^dfBd |e4 "$" ||
V:2
L:1/16
z4 |[G,2D2][B,2D2] [G,2D2][B,2D2]|[G,2D2][B,2D2] [A,2D2][C2D2] |[A,2D2][C2D2] [A,2D2][C2D2] | [A,2D2]z2 [G,2D2][B,2D2]|[G,2D2][B,2D2] [G,2D2][B,2D2]|[G,2D2][B,2D2] [A,2D2][C2D2] |[A,2D2][C2D2] [A,2D2][C2D2]|[B,4D4] ||
z4|G,B,DB, G,B,DB, |A,CDC A,CDC |DFAF DFAF |G,B,DF GDB,A, |G,B,DB, G,B,DB, |A,CDC A,CDC | DFAF DFAF |G4 :|| DFAF DFAF |G4 ||
z4 |EGEG EGEG |FAFA FAFA |B,^C^DC B,^C^DB,|EGBB BAGF |EGEG EGEG |FAFA FAFA |B,^C^DC B,^C^DB,|E4 || %%
X:1
T:La Nouvelle Gigue
K:G
Z:Stephan Steiner
M:2/4
L:1/16
P:A
V:1
"$"(d>c)|B2G2 G>BA>B |c>BA>G F>DE>F |G>AB>c B>cd>e |.A2d2 d2(d>c)|
B2G2 G>BA>B |c>BA>G F>DE>F |G>BA>c B>dc>A |G2[B,2G2][B,2G2] :|
P:B
|: b>g |a>c"tr"c2 A>c "tr"c2 |B>G"tr"G2 E>Gc>E |F>DA>F G>DG>B |.A2 .[F2d2] .[F2d2](b>g) |
a>c"tr"c2 A>c "tr"c2 |B>db>a g>fe>d |c>BA>G F>AD>F |G2[B,2G2][B,2G2] "$":|
P:C
B2 |e>ee>e e>gf>e |^d>ef>d B>ba>f |g>fe>^d e>BA>G |F>GF>E ^D2B2 |
e>ee>e e>gf>e |^d>fb>a g>fe>d |e>Bc>A G>BA>F |E2E2E2 :||
V:2
L:1/16
(B>A)|G2D2 B,>GF>G |A>GF>E D2C2 |B,2G2 G>AB>G |F2[F2A2][F2A2] (B>A) |B2G2 B,>GF>G |A>GF>E D2C2 |B,2E>A G>BA>F |G2D2B,2 :|
g>B|c2A2 F2A2 |G2D2 C2E2 |.A,2 .C2 .B,2.G2 |.F2[,A2F2][,A2F2] g>B |.c2.A2 .F2.A2 |G>dg>f e>dc>B|A>G F>E D2 [C2D2] | [B,2D2][B,2D2][B,2D2] :|: B2 |[B,2G2][B,2G2] [B,2G2][B,2G2]|[B,2F2][B,2F2] [B,2F2][B,2F2]|E2E>F G>GF>E |^D2[B,2F2][B,2F2]B2 |[B,2G2][B,2G2][B,2G2][B,2G2]|[B,2F2][B,2F2][B,2F2][B,2F2]|G>GA>F E>GF>^D|E2[B,2E2] [G,2E2] :|| %%
X:1
T:Les Bois
Z:Stephan "Stoney" Steiner
S:Landrin: Potpourri françois de contre danse ancienne
K:G
M:6/8
L:1/8
GGG |d2 d e2 f |g2 g gag |fgf efe|d3 ::def |g2d d2c |"+"B2B BcB |
AGA BcB |A2G def |g2d d2c |"+"B3 d2A |c2B AGF |G3 :|] %%
X:1
T:La Camargos
S:Landrin - Potpourri françois des contre-danse ancienne (~1760)
Z:Stephan Steiner
K:Gm
M:6/8
L:1/8
P:part A (play AA BA CA)
Bc "$"|:d2d dcd |B2B BAB |cde dcB |A2A ABc |d2d dcd |B2B cde |dcB AGF |1 G3 zBc :|2 G3 ||
P:part B
DGA |B3 BAB |c3 cBc |ded dcB |A3 AGA | B3 BAB |c3 cBc |ded dBc |ded dBc "$"||
P:part C
Gba |g^fg aba |g^fg aba |gab ag=f |=e3 ede |f2 f f=ef |g2 g gfg |aba =e^fg |^f2f fBc "$"|| %%
X:1
T:La Boulangere
S:Landrin: Potpourri françois de contre danse ancienne
Z:Stephan "Stoney" Steiner
K:G
M:6/8
L:1/8
G2G |c2c cdc |B2c d2d |A2B "+"B3 |A3 :: A2A |A2G A2B |
G2G GFE |F2G AGA |D2G GFE |F2G "+"A3|G3 :|] %%
X:1
T:La Colombe
S:Landrin: Potpourri françois de contre danse ancienne
K:Gm
M:6/8
L:1/8
GAB|Bcd d=e^f |g3 gfe|dcB Adc |B2A GAB |Bcd d=e^f |g3 gfe|dcB AG^F |G3"fine" :|
|: ABc |~B2A ABc |~B2A cBA |BAG ^FGA |D3 ABc |~B2A ABc |~B2A Bcd |Bcd dcB |A3 "D.C.":| %%
X:1
T:La Matelote Holandaise
C:trad.
Z:Stephan Steiner
S:Landrin: Pot-pourri francois de contre-danses anciennes tel qu'il se danse chez la Reine
M:4/4
L:1/8
K:A
EFG|A2A2 AcBA |d2 d2 dfdB |cecA Bcdc |BAGF EEFG |A2A2 AcBA |
d2 d2 dfdB |cecA BdBG |A4 z :: Bcd | e2e2 efec |d2 B2-BABc |
d2d2 dfdB |c2 A2-A2 c2 |BGEG BGEB |d4 e4 |dcBA cBAG |A4 z :| z|
K:Am
|: E2 |A^GAB A2B2 |cBcd c2e2 |dcBA cBA^G |A^GAB A2E2 |A^GAB A2B2 |cBcd c2e2 |
dcBA cBA^G |1 A6 :|2 A4 z |: Bcd |e2e2 efec |dBGB dBGB |
c2fe dcBA |^GABG E2e2 |aecA aecA |f4 fedc |edcB cBAG |A4 z :|]
%%
X:1
T:La Menagere
Z:Stephan "Stoney" Steiner
S:Landrin: Potpourri françois de contre danse ancienne
K:Dm
M:4/4
L:1/8
defg |a2a2g2a2 |e2f2 "+"f4 |e2f2 "+"f4 |e4 :: f4 |e2d2^c2d2 |A4 efge |
f2d2 efge |f2d2 f4 |e2d2^c2 d2 |[D4A4] defg |a2 gf "+"e3 d |d4 :|| %%
up
0 users have voted.
Powered by Drupal, an open source content management system